(─━┘_└━─)/ 머리만1톤(Head1Ton)

[따라하기] NOT NULL 속성 열 추가하기

USE Sample;

GO

-- 테스트 테이블을 생성합니다.

SELECT identity(int,1,1) as Seq, p1.*

INTO LargeTabAddNotNullCol

FROM AdventureWorks.Production.Product p1

             CROSS JOIN AdventureWorks.Production.Product p2;

GO

-- NULL 속성으로 열을 추가합니다.

ALTER TABLE LargeTabAddNotNullCol

ADD NotNullCol char(50) NULL;

GO

-- 업데이터 성능을 위하여 인덱스를 생성합니다.

CREATE INDEX IDX_1 ON LargeTabAddNotNullCol (NotNullCol);

GO

-- 전체 데이터를 분할하여 업데이트합니다.

DECLARE @ROWS int

SET @ROWS=10000;

UPDATE TOP (@ROWS) LargeTabAddNotNullCol SET NotNullCol = 'default value'

WHERE NotNullCol IS NULL;

WHILE @@ROWCOUNT = 10000

BEGIN

    UPDATE TOP (@ROWS) LargeTabAddNotNullCol

             SET NotNullCol = 'default value'

    WHERE NotNullCol IS NULL;

END

GO

-- NotNullCol 열에 NULL 값이 있는지 확인합니다.

SELECT count(*) FROM LargeTabAddNotNullCol WHERE NotNullCol IS NULL

-- NotNullCol 열에 존재하는 인덱스를 제거합니다.

DROP INDEX LargeTabAddNotNullCol.IDX_1;

GO

-- NotNullCol 열을 NOT NULL 속성으로 변경합니다.

ALTER TABLE LargeTabAddNotNullCol

ALTER COLUMN NotNullCol char(50) NOT NULL;

GO